mirror of
https://github.com/checkpoint-restore/criu.git
synced 2026-07-23 18:19:39 +00:00
8b99809a4e
The objective is to only do parasite code linking once -- when we link parasite objects with compel plugin(s). So, let's use ar (rather than ld) here. This way we'll have a single ld invocation with the proper flags (from compel ldflags) etc. There are two tricks in doing it: 1. The order of objects while linking is important. Therefore, compel plugins should be the last to add to ld command line. 2. Somehow ld doesn't want to include parasite-head.o in the output (probably because no one else references it), so we have to force it in with the modification to our linker scripts. NB: compel makefiles are still a big mess, but I'll get there. Acked-by: Cyrill Gorcunov <gorcunov@openvz.org> Signed-off-by: Kir Kolyshkin <kir@openvz.org> Signed-off-by: Andrei Vagin <avagin@virtuozzo.com>
40 lines
578 B
ArmAsm
40 lines
578 B
ArmAsm
OUTPUT_ARCH(powerpc:common64)
|
|
EXTERN(__export_parasite_head_start)
|
|
|
|
SECTIONS
|
|
{
|
|
.text : {
|
|
*(.head.text)
|
|
ASSERT(DEFINED(__export_parasite_head_start),
|
|
"Symbol __export_parasite_head_start is missing");
|
|
*(.text*)
|
|
*(.compel.exit)
|
|
*(.compel.init)
|
|
}
|
|
|
|
.data : {
|
|
*(.data*)
|
|
*(.bss*)
|
|
}
|
|
|
|
.rodata : {
|
|
*(.rodata*)
|
|
*(.got*)
|
|
}
|
|
|
|
.toc : ALIGN(8) {
|
|
*(.toc*)
|
|
}
|
|
|
|
/DISCARD/ : {
|
|
*(.debug*)
|
|
*(.comment*)
|
|
*(.note*)
|
|
*(.group*)
|
|
*(.eh_frame*)
|
|
}
|
|
|
|
/* Parasite args should have 4 bytes align, as we have futex inside. */
|
|
. = ALIGN(4);
|
|
__export_parasite_args = .;
|
|
}
|